【MQL】アジア・欧州・アメリカ時間帯別でトレードするEA【中級編】

//日付をまたぐ時間帯(21時〜翌6時)はOR条件、それ以外はelse ifで確実にどれか1つに分類する
if(NowHour >= StartTimeA || NowHour < EndTimeA)
   TimeSignal = JpnTime;
else if(NowHour >= EndTimeA && NowHour < EndTimeE)
   TimeSignal = EurTime;
else
   TimeSignal = UsaTime;

bool HasPosition()
  {
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES)) continue;
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==MagicNumber)
         return(true);
     }
   return(false);
  }

//+------------------------------------------------------------------+
//|                                                  JP-EU-NY-EA.mq4 |
//|                     Copyright 2020, FX-EA System Project Creator |
//|                        https://creator.fx-ea-system-project.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, FX-EA System Project Creator"
#property link      "https://creator.fx-ea-system-project.com/"
#property version   "1.01"
#property strict

/*パラメーター*/
input int TakeProfit = 5;//利確
input int StopLoss = 50;//ストップロス
input double Lots = 0.01;//ロット数
input int MagicNumber = 12345;//マジックナンバー

input int StartTimeA = 21;//アジア開始時間（サーバー時刻）
input int EndTimeA = 6;//アジア終了時間
input int EndTimeE = 12;//欧州終了時間
input int EndTimeU = 21;//アメリカ終了時間

input int RSI_period = 14;//RSI期間
input int MA_Short_period = 50;//短期移動平均線期間
input int MA_Long_period = 100;//長期移動平均線期間

//+------------------------------------------------------------------+
//| このEA(マジックナンバー)のポジションを保有しているか判定する      |
//+------------------------------------------------------------------+
bool HasPosition()
  {
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES)) continue;
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==MagicNumber)
         return(true);
     }
   return(false);
  }

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   //既にポジションを持っている場合は新規エントリーしない
   if(HasPosition())
      return;

   int NowHour = TimeHour(TimeCurrent());//現在の時間
   int TimeSignal;//それぞれの時間を代入する変数
   int JpnTime = 0;//日本時間
   int EurTime = 1;//欧州時間
   int UsaTime = 2;//欧米時間

   double RSI;//RSI
   double genMA_Short,genMA_Long;//現在の短期移動平均線と現在の長期移動平均線
   double kakoMA_Short,kakoMA_Long;//1つ前の短期移動平均線と1つ前の長期移動平均線

   //日付をまたぐ時間帯(21時〜翌6時)はOR条件、それ以外はelse ifで確実にどれか1つに分類する
   if(NowHour >= StartTimeA || NowHour < EndTimeA)
      TimeSignal = JpnTime;
   else if(NowHour >= EndTimeA && NowHour < EndTimeE)
      TimeSignal = EurTime;
   else
      TimeSignal = UsaTime;

   RSI = iRSI(Symbol(),0,RSI_period,PRICE_CLOSE,0);//RSI
   kakoMA_Short = iMA(NULL,0,MA_Short_period,0,MODE_SMA,PRICE_CLOSE,1);//1つ前の短期移動平均線
   kakoMA_Long  = iMA(NULL,0,MA_Long_period,0,MODE_SMA,PRICE_CLOSE,1);//1つ前の長期移動平均線
   genMA_Short  = iMA(NULL,0,MA_Short_period,0,MODE_SMA,PRICE_CLOSE,0);//現在の短期移動平均線
   genMA_Long   = iMA(NULL,0,MA_Long_period,0,MODE_SMA,PRICE_CLOSE,0);//現在の長期移動平均線

   int ticket;

   if(TimeSignal == JpnTime && RSI < 30)//日本時間でRSIが30より小さい場合
     {
      ticket = OrderSend(Symbol(),OP_BUY,Lots,Ask,3,Ask-StopLoss*Point*10,Ask+TakeProfit*Point*10,"Order Long",MagicNumber,0,Lime);
      if(ticket < 0) Print("買い注文に失敗しました。エラーコード=",GetLastError());
     }
   if(TimeSignal == JpnTime && RSI > 70)//日本時間でRSIが70より大きい場合
     {
      ticket = OrderSend(Symbol(),OP_SELL,Lots,Bid,3,Bid+StopLoss*Point*10,Bid-TakeProfit*Point*10,"Order Short",MagicNumber,0,Red);
      if(ticket < 0) Print("売り注文に失敗しました。エラーコード=",GetLastError());
     }
   if(TimeSignal == EurTime && kakoMA_Short < kakoMA_Long && genMA_Short > genMA_Long)//欧州時間でゴールデンクロスした場合
     {
      ticket = OrderSend(Symbol(),OP_BUY,Lots,Ask,3,Ask-StopLoss*Point*10,Ask+TakeProfit*Point*10,"Order Long",MagicNumber,0,Lime);
      if(ticket < 0) Print("買い注文に失敗しました。エラーコード=",GetLastError());
     }
   if(TimeSignal == EurTime && kakoMA_Short > kakoMA_Long && genMA_Short < genMA_Long)//欧州時間でデッドクロスした場合
     {
      ticket = OrderSend(Symbol(),OP_SELL,Lots,Bid,3,Bid+StopLoss*Point*10,Bid-TakeProfit*Point*10,"Order Short",MagicNumber,0,Red);
      if(ticket < 0) Print("売り注文に失敗しました。エラーコード=",GetLastError());
     }
   if(TimeSignal == UsaTime && RSI > 80)//米国時間でRSIが80より大きい場合
     {
      ticket = OrderSend(Symbol(),OP_BUY,Lots,Ask,3,Ask-StopLoss*Point*10,Ask+TakeProfit*Point*10,"Order Long",MagicNumber,0,Lime);
      if(ticket < 0) Print("買い注文に失敗しました。エラーコード=",GetLastError());
     }
   if(TimeSignal == UsaTime && RSI < 20)//米国時間でRSIが20より小さい場合
     {
      ticket = OrderSend(Symbol(),OP_SELL,Lots,Bid,3,Bid+StopLoss*Point*10,Bid-TakeProfit*Point*10,"Order Short",MagicNumber,0,Red);
      if(ticket < 0) Print("売り注文に失敗しました。エラーコード=",GetLastError());
     }
  }
//+------------------------------------------------------------------+