【MQL4】複数EA・インジケーター間で値を共有するGlobalVariableSet/Getの使い方と『消し忘れ』の罠

//+------------------------------------------------------------------+
//|                                    GlobalDailyTradeLimit.mq4      |
//|                     Copyright 2026, FX-EA System Project Creator |
//|                        https://creator.fx-ea-system-project.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, FX-EA System Project Creator"
#property link      "https://creator.fx-ea-system-project.com/"
#property version   "1.00"
#property strict

input int    MagicNumber      = 56789;//マジックナンバー(このEA固有)
input double Lots             = 0.01;//ロット数
input int    TakeProfit       = 20;//利確(pips)
input int    StopLoss         = 20;//損切り(pips)
input int    Slippage         = 3;//スリッページ
input int    MaxDailyTrades   = 5;//1日あたりの新規エントリー上限(同じ接頭辞を使う全EA合算)
input string CounterPrefix    = "DailyTradeCount_";//グローバル変数の接頭辞

//+------------------------------------------------------------------+
//| 今日の日付を含むグローバル変数名を作る                             |
//+------------------------------------------------------------------+
string DailyCounterName()
  {
   return(CounterPrefix + TimeToString(TimeCurrent(), TIME_DATE));
  }

//+------------------------------------------------------------------+
//| 今日すでに何回エントリーしたかを取得する(なければ0)                 |
//+------------------------------------------------------------------+
int GetTodayTradeCount()
  {
   string name = DailyCounterName();
   if(!GlobalVariableCheck(name))
      return(0);
   return((int)GlobalVariableGet(name));
  }

//+------------------------------------------------------------------+
//| 今日のエントリー回数を1増やす                                     |
//+------------------------------------------------------------------+
void IncrementTodayTradeCount()
  {
   string name = DailyCounterName();
   GlobalVariableSet(name, GetTodayTradeCount()+1);
  }

//+------------------------------------------------------------------+
//| このEA(マジックナンバー)のポジションを保有しているか判定する      |
//+------------------------------------------------------------------+
bool HasPosition()
  {
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES)) continue;
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==MagicNumber)
         return(true);
     }
   return(false);
  }

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(HasPosition())
      return;

   if(GetTodayTradeCount() >= MaxDailyTrades)
      return;//このEA単体ではなく、同じ接頭辞を使う他のEAの分も合算された回数

   //ここは説明用のシンプルな条件。実際にはお好みのエントリーロジックに置き換える
   double ma50  = iMA(NULL,0,50,0,MODE_SMA,PRICE_CLOSE,0);
   double ma100 = iMA(NULL,0,100,0,MODE_SMA,PRICE_CLOSE,0);

   if(ma50 > ma100)
     {
      double sl = Ask-StopLoss*Point*10;
      double tp = Ask+TakeProfit*Point*10;
      int ticket = OrderSend(Symbol(),OP_BUY,Lots,Ask,Slippage,sl,tp,"Global Limit Buy",MagicNumber,0,Blue);
      if(ticket >= 0)
         IncrementTodayTradeCount();
      else
         Print("買い注文に失敗しました。エラーコード=",GetLastError());
     }
  }
//+------------------------------------------------------------------+