【MQL4】雲の上限・下限は毎回変わる｜一目均衡表の『雲抜け』だけを検知して矢印表示するインジケーターの作り方

//+------------------------------------------------------------------+
//|                              IchimokuCloudBreakout.mq4            |
//|                     Copyright 2026, FX-EA System Project Creator |
//|                        https://creator.fx-ea-system-project.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, FX-EA System Project Creator"
#property link      "https://creator.fx-ea-system-project.com/"
#property version   "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 DodgerBlue
#property indicator_color2 OrangeRed

input int TenkanSen   = 9;//転換線の期間
input int KijunSen    = 26;//基準線の期間
input int SenkouSpanB = 52;//先行スパンBの期間
input int ArrowGap    = 20;//高値・安値から矢印を離すpoint数

double UpArrow[];
double DownArrow[];
datetime lastAlertBarTime = 0;//直前にAlertを出した確定足の時刻(同じ足で連発しないためのガード)

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   SetIndexBuffer(0,UpArrow);
   SetIndexStyle(0,DRAW_ARROW,STYLE_SOLID,1);
   SetIndexArrow(0,233);
   SetIndexEmptyValue(0,EMPTY_VALUE);

   SetIndexBuffer(1,DownArrow);
   SetIndexStyle(1,DRAW_ARROW,STYLE_SOLID,1);
   SetIndexArrow(1,234);
   SetIndexEmptyValue(1,EMPTY_VALUE);

   IndicatorShortName("Ichimoku Cloud Breakout");
   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                 const int prev_calculated,
                 const datetime &time[],
                 const double &open[],
                 const double &high[],
                 const double &low[],
                 const double &close[],
                 const long &tick_volume[],
                 const long &volume[],
                 const int &spread[])
  {
   int neededBars = SenkouSpanB + KijunSen + 3;
   if(rates_total < neededBars)
      return(0);

   ArraySetAsSeries(close,true);

   int limit=(prev_calculated==0) ? rates_total-2 : rates_total-prev_calculated+1;
   if(limit > rates_total-2)
      limit = rates_total-2;

   for(int i=limit;i>=1;i--)
     {
      UpArrow[i]=EMPTY_VALUE;
      DownArrow[i]=EMPTY_VALUE;

      double spanA_cur  = iIchimoku(NULL,0,TenkanSen,KijunSen,SenkouSpanB,MODE_SENKOUSPANA,i);
      double spanB_cur  = iIchimoku(NULL,0,TenkanSen,KijunSen,SenkouSpanB,MODE_SENKOUSPANB,i);
      double spanA_prev = iIchimoku(NULL,0,TenkanSen,KijunSen,SenkouSpanB,MODE_SENKOUSPANA,i+1);
      double spanB_prev = iIchimoku(NULL,0,TenkanSen,KijunSen,SenkouSpanB,MODE_SENKOUSPANB,i+1);

      double cloudTop_cur    = MathMax(spanA_cur, spanB_cur);
      double cloudBottom_cur = MathMin(spanA_cur, spanB_cur);
      double cloudTop_prev   = MathMax(spanA_prev, spanB_prev);
      double cloudBottom_prev= MathMin(spanA_prev, spanB_prev);

      //上抜け: 1本前は雲の上限以下、今は雲の上限を超えた
      if(close[i] > cloudTop_cur && close[i+1] <= cloudTop_prev)
         UpArrow[i]=low[i]-ArrowGap*Point;
      //下抜け: 1本前は雲の下限以上、今は雲の下限を割った
      else if(close[i] < cloudBottom_cur && close[i+1] >= cloudBottom_prev)
         DownArrow[i]=high[i]+ArrowGap*Point;
     }

   //形成中の足には表示しない
   UpArrow[0]=EMPTY_VALUE;
   DownArrow[0]=EMPTY_VALUE;

   //直近の確定足(shift=1)でブレイクが起きていればAlertで通知する(同じ足で連発しない)
   datetime barTime1 = iTime(NULL,0,1);
   if(barTime1 != lastAlertBarTime)
     {
      if(UpArrow[1] != EMPTY_VALUE)
        {
         Alert(Symbol()," ",Period(),"分足: 一目均衡表の雲を上抜けました (",TimeToString(barTime1,TIME_DATE|TIME_MINUTES),")");
         lastAlertBarTime = barTime1;
        }
      else if(DownArrow[1] != EMPTY_VALUE)
        {
         Alert(Symbol()," ",Period(),"分足: 一目均衡表の雲を下抜けました (",TimeToString(barTime1,TIME_DATE|TIME_MINUTES),")");
         lastAlertBarTime = barTime1;
        }
     }

   return(rates_total);
  }
//+------------------------------------------------------------------+