【MQL4】主要8通貨の通貨強弱をパネルで表示するインジケーターの作り方

//+------------------------------------------------------------------+
//|                                   CurrencyStrengthPanel.mq4       |
//|                     Copyright 2026, FX-EA System Project Creator |
//|                        https://creator.fx-ea-system-project.com/ |
//+------------------------------------------------------------------+
#property strict
#property indicator_chart_window

input int InpLookbackBars = 20; //強弱を計算する期間(本数)

string Symbols7[7] = {"EURUSD","GBPUSD","AUDUSD","NZDUSD","USDJPY","USDCAD","USDCHF"};
string PanelPrefix = "CcyStrength_";

int OnInit()
  {
   for(int i = 0; i < 7; i++)
      SymbolSelect(Symbols7[i], true); //Market Watchに追加(iCloseの0返り対策)

   for(int i = 0; i < 8; i++)
     {
      string name = PanelPrefix + IntegerToString(i);
      ObjectCreate(0, name, OBJ_LABEL, 0, 0, 0);
      ObjectSetInteger(0, name, OBJPROP_CORNER, CORNER_RIGHT_UPPER);
      ObjectSetInteger(0, name, OBJPROP_XDISTANCE, 10);
      ObjectSetInteger(0, name, OBJPROP_YDISTANCE, 20 + i * 18);
      ObjectSetInteger(0, name, OBJPROP_FONTSIZE, 10);
     }

   return(INIT_SUCCEEDED);
  }

void OnDeinit(const int reason)
  {
   for(int i = 0; i < 8; i++)
      ObjectDelete(0, PanelPrefix + IntegerToString(i));
  }

double PercentChange(string symbol)
  {
   double past = iClose(symbol, 0, InpLookbackBars);
   double now  = iClose(symbol, 0, 0);
   if(past == 0)
      return(0); //履歴未取得時の保険(ゼロ除算防止)

   return((now - past) / past * 100.0);
  }

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   double chgEURUSD = PercentChange("EURUSD");
   double chgGBPUSD = PercentChange("GBPUSD");
   double chgAUDUSD = PercentChange("AUDUSD");
   double chgNZDUSD = PercentChange("NZDUSD");
   double chgUSDJPY = PercentChange("USDJPY");
   double chgUSDCAD = PercentChange("USDCAD");
   double chgUSDCHF = PercentChange("USDCHF");

   double usd = (-chgEURUSD - chgGBPUSD - chgAUDUSD - chgNZDUSD
                 + chgUSDJPY + chgUSDCAD + chgUSDCHF) / 7.0;

   string names[8]  = {"USD","EUR","GBP","AUD","NZD","JPY","CAD","CHF"};
   double values[8];
   values[0] = usd;
   values[1] = chgEURUSD;
   values[2] = chgGBPUSD;
   values[3] = chgAUDUSD;
   values[4] = chgNZDUSD;
   values[5] = -chgUSDJPY;
   values[6] = -chgUSDCAD;
   values[7] = -chgUSDCHF;

   for(int i = 0; i < 8; i++)
     {
      string name = PanelPrefix + IntegerToString(i);
      string sign = (values[i] >= 0) ? "+" : "";
      string text = StringFormat("%s  %s%.2f%%", names[i], sign, values[i]);

      ObjectSetString(0, name, OBJPROP_TEXT, text);
      ObjectSetInteger(0, name, OBJPROP_COLOR, values[i] >= 0 ? clrLimeGreen : clrOrangeRed);
     }

   return(rates_total);
  }