【MQL5】決済のたびにCSVへ追記するだけでは限界?組み込みSQLiteをDatabaseOpenで使う方法

//+------------------------------------------------------------------+
//|                                  SqliteTradeLogEA.mq5             |
//|                     Copyright 2026, FX-EA System Project Creator |
//|                        https://creator.fx-ea-system-project.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, FX-EA System Project Creator"
#property link      "https://creator.fx-ea-system-project.com/"
#property version   "1.00"

int g_db = INVALID_HANDLE;

//+------------------------------------------------------------------+
//| Expert initialization function                                    |
//+------------------------------------------------------------------+
int OnInit()
  {
   g_db = DatabaseOpen("TradeLog.sqlite", DATABASE_OPEN_READWRITE | DATABASE_OPEN_CREATE);
   if(g_db == INVALID_HANDLE)
     {
      Print("DatabaseOpenに失敗しました。error=", GetLastError());
      return(INIT_FAILED);
     }

   if(!DatabaseExecute(g_db,
      "CREATE TABLE IF NOT EXISTS trade_log (symbol TEXT, profit REAL, close_time INTEGER)"))
     {
      Print("CREATE TABLEに失敗しました。error=", GetLastError());
      return(INIT_FAILED);
     }
   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+
//| Expert deinitialization function                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   PrintProfitBySymbol(); //終了時に集計結果を確認する(本来は任意のタイミングでよい)
   if(g_db != INVALID_HANDLE)
      DatabaseClose(g_db);
  }

//+------------------------------------------------------------------+
//| 決済(部分決済含む)のたびに1行記録する                              |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                         const MqlTradeRequest &request,
                         const MqlTradeResult &result)
  {
   if(trans.type != TRADE_TRANSACTION_DEAL_ADD)
      return;
   if(!HistoryDealSelect(trans.deal))
      return;
   if(HistoryDealGetInteger(trans.deal, DEAL_ENTRY) != DEAL_ENTRY_OUT)
      return; //決済(手仕舞い)の約定だけを記録する

   string   symbol = HistoryDealGetString(trans.deal, DEAL_SYMBOL);
   double   profit  = HistoryDealGetDouble(trans.deal, DEAL_PROFIT);
   datetime t       = (datetime)HistoryDealGetInteger(trans.deal, DEAL_TIME);

   string sql = StringFormat(
      "INSERT INTO trade_log(symbol, profit, close_time) VALUES('%s', %.2f, %d)",
      symbol, profit, (long)t);

   if(!DatabaseExecute(g_db, sql))
      Print("INSERTに失敗しました。error=", GetLastError());
  }

//+------------------------------------------------------------------+
//| 銘柄ごとの合計損益を集計してPrintする                              |
//+------------------------------------------------------------------+
void PrintProfitBySymbol()
  {
   int request = DatabasePrepare(g_db, "SELECT symbol, SUM(profit) FROM trade_log GROUP BY symbol");
   if(request == INVALID_HANDLE)
     {
      Print("DatabasePrepareに失敗しました。error=", GetLastError());
      return;
     }

   while(DatabaseRead(request))
     {
      string symbol;
      double totalProfit;
      DatabaseColumnText(request, 0, symbol);
      DatabaseColumnDouble(request, 1, totalProfit);
      Print(symbol, " の合計損益: ", DoubleToString(totalProfit, 2));
     }

   if(GetLastError() != ERR_DATABASE_NO_MORE_DATA)
      Print("DatabaseReadが異常終了しました。error=", GetLastError());

   DatabaseFinalize(request);
  }
//+------------------------------------------------------------------+